| /* SPDX-License-Identifier: GPL-2.0 */ |
| #include <linux/linkage.h> |
| #include <asm/assembler.h> |
| #include "abort-macro.S" |
| /* |
| * Function: v5tj_early_abort |
| * |
| * Params : r2 = pt_regs |
| * : r4 = aborted context pc |
| * : r5 = aborted context psr |
| * |
| * Returns : r4 - r11, r13 preserved |
| * |
| * Purpose : obtain information about current aborted instruction. |
| * Note: we read user space. This means we might cause a data |
| * abort here if the I-TLB and D-TLB aren't seeing the same |
| * picture. Unfortunately, this does happen. We live with it. |
| */ |
| .align 5 |
| ENTRY(v5tj_early_abort) |
| mrc p15, 0, r1, c5, c0, 0 @ get FSR |
| mrc p15, 0, r0, c6, c0, 0 @ get FAR |
| bic r1, r1, #1 << 11 | 1 << 10 @ clear bits 11 and 10 of FSR |
| tst r5, #PSR_J_BIT @ Java? |
| bne do_DataAbort |
| do_thumb_abort fsr=r1, pc=r4, psr=r5, tmp=r3 |
| ldreq r3, [r4] @ read aborted ARM instruction |
| uaccess_disable ip @ disable userspace access |
| teq_ldrd tmp=ip, insn=r3 @ insn was LDRD? |
| beq do_DataAbort @ yes |
| tst r3, #1 << 20 @ L = 0 -> write |
| orreq r1, r1, #1 << 11 @ yes. |
| b do_DataAbort |
